Zeigt place-nodes an, bei denen potenziell noch keine Gebäude gemappt wurden. Landuse=residential ohne place-nodes werden nicht berücksichtigt!

Achtung: Kartenausschnitt nicht zu groß wählen! Evtl. timeout individuell anpassen

Overpass-Turbo Abfrage:

http://overpass-turbo.eu/s/qSk

Script:

/* Find place-nodes without buildings around */

[out:json][timeout:90];

//get all place-nodes in bbox for towns, villages, hamlets and isolated_dwellings
( node["place"="town"]({{bbox}}); )              ->.towns;
( node["place"="village"]({{bbox}}); )           ->.villages;
( node["place"="hamlet"]({{bbox}}); )            ->.hamlets;
( node["place"="isolated_dwelling"]({{bbox}}); ) ->.isolated_dwellings;

//get buildings around place-nodes (radius 100m)
way[building](around.towns:100)                  ->.town_buildings;
way[building](around.villages:100)               ->.village_buildings;
way[building](around.hamlets:100)                ->.hamlet_buildings;
way[building](around.isolated_dwellings:100)     ->.isolated_dwelling_buildings;

//get places-nodes without buildings around
(.towns; - node.towns(around.town_buildings:100);)          ->.empty_town;
(.villages; - node.villages(around.village_buildings:100);) ->.empty_village;
(.hamlets; - node.hamlets(around.hamlet_buildings:100);)    ->.empty_hamlet;
(.isolated_dwellings; - node.isolated_dwellings(around.isolated_dwelling_buildings:100);) ->.empty_isolated_dwelling;

//print results
(.empty_town; .empty_village; .empty_hamlet; .empty_isolated_dwelling;);
out geom;

//colours for the results 
{{style:
node[place=town] { color:black; fill-color:red; }
node[place=village] { color:black; fill-color:blue; }
node[place=hamlet] { color:black; fill-color:yellow; }
node[place=isolated_dwelling] { color:black; fill-color:magenta; }
}}